Edit (another) file in the same directory without changing cwd

Question

It needs to support completion.

An example use case would be: I'm on a given project (so a certain cwd) but need to update one of my Vim files. If they are already opened so navigate buffers or navigate them using MRU.

But often if I need another Vim file I used type mc to switch the cwd then :e filename. Then need to switch back.

It is also confusing because git folder changes when this happens.

Thanks for sharing your solution! I believe it would be helpful to others if you could describe your use case. I suppose an example would be helpful. — Vivian De Smedt, Sep 01 '23 at 14:27
I am surprised you haven't encounter this yourself every hour on average — eyal karni, Sep 01 '23 at 17:36
I'm using vim-rooter that automatically change the cwd and fuzzy file engine like vim-clap or telescope. But I like very much your solution :-) — Vivian De Smedt, Sep 01 '23 at 17:50

score 4 · Answer 1 · edited Dec 25 '23 at 05:18

4

This all is implemented long time ago by builtin command :h :find used along with option :h 'path'.

Namely:

set path=.
find FILENAME

which could be made a command.

edited Dec 25 '23 at 05:18

eyal karni

1,106
9
33

answered Sep 02 '23 at 01:09

Matt

20,685
1
11
24

right. I didn't know that! – eyal karni Sep 02 '23 at 20:59
On a second thought, it is quite not easy to make this into command because you need to specify correctly the completion function which I am not sure how to do. Abbreviation could work. – eyal karni Dec 25 '23 at 05:22

eyal karni · Answer 2 · 2023-12-25T05:20:30.360

The advantage here is that it filters only on files (not directories). Also, it is a prepared command.

:com! -nargs=1 -bang -complete=customlist,EditFileComplete
        \ EditFile exec "edit<bang> ". expand("%:p:h")."/<args>"
:fun! EditFileComplete(A,L,P)
:    return map(filter(split(glob(expand("%:p:h").'/*'.(len(a:A)>1 ? a:A . "*" : '')), "\n"),'filewritable(v:val) != 2' ),'fnamemodify(v:val, ":t")' )
:endfun

D. Ben Knoble · Accepted Answer · 2024-01-01T15:49:30.197

My solution doesn't involve tweaking path or a custom command (which isn't as scalable to other forms of :edit, like :split): I use a command-line mapping on %% to insert the directory. It goes like this:

cnoremap <expr> %% bk#filename#command_dir('%%')

where bk#filename#command_dir is an autoloaded function:


" Get the directory of a file
" - On Ex command lines, returns the directory of the file ('./' for new files)
" - On other command lines (/,?) returns the keymap used to trigger it
function! bk#filename#command_dir(keymap) abort
  let l:command_type = getcmdtype()
  if l:command_type isnot# ':'
    return a:keymap
  endif
  let l:dir = expand('%:h')
  if empty(l:dir)
    let l:dir = '.'
  endif
  return l:dir . (has('win64') || has('win32') || has('win32unix') ? '\' : '/')
endfunction

Now I type :edit %%file, :vsplit %%, or other variants when I need to (actually I have mappings that insert that automatically).

I like it. I have made it os independent because the / didnt bode well in windows. — eyal karni, Dec 30 '23 at 19:19
@eyalkarni I've edited your edit to align better with my preferred style. Note that has('win16') is documented as always false, so I've also changed the condition a bit. — D. Ben Knoble, Jan 01 '24 at 15:49

Edit (another) file in the same directory without changing cwd

3 Answers3