How can I close the Netrw buffer?

Question

I tried both :bd and :bw and neither work.

It's in its own window/pane? :close? – B Layer Dec 22 '17 at 02:16 — B Layer, Dec 22 '17 at 02:16

score 13 · Answer 1 · answered May 26 '19 at 01:07

13

The autocmd FileType netrw setl bufhidden=wipe still leaves one buffer open. I found this solution, which closes it after opening the file:

let g:netrw_fastbrowse = 0

over at the discussion on https://github.com/tpope/vim-vinegar/issues/13

answered May 26 '19 at 01:07

Brian C. Lane

231
2
4

Using both (autocmd and fastbrow) worked for me – lucasgrvarela Dec 21 '22 at 03:47

score 8 · Answer 2 · answered Dec 22 '17 at 17:16

I've had this problem, when using Vinegar to make netrw easier to use. I found a site that offers one solution here, and more solutions here.

The solution that worked for me, was to add this to my .vimrc:

autocmd FileType netrw setl bufhidden=wipe

For the sake of completeness, other solutions:

@serebrov on Github:

function! QuitNetrw()
  for i in range(1, bufnr($))
    if buflisted(i)
      if getbufvar(i, '&filetype') == "netrw"
        silent exe 'bwipeout ' . i
      endif
    endif
  endfor
endfunction

autocmd MyAutoCmd VimLeavePre *  call QuitNetrw()

@slashfoo on Github:

" Remove 'set hidden'
set nohidden

augroup netrw_buf_hidden_fix
    autocmd!

    " Set all non-netrw buffers to bufhidden=hide
    autocmd BufWinEnter *
                \  if &ft != 'netrw'
                \|     set bufhidden=hide
                \| endif

augroup end

The first solution was posted by @tpope, also on github.

score 1 · Answer 3 · answered Feb 01 '21 at 23:32

Tried all kind of solutions from here and some other places, none worked as expected, respectively I didn't like the implementation much (e.g. the one using augroup netrw_buf_hidden_fix), so I ended up with this for closing netrw using Esc or q

autocmd FileType netrw nnoremap <buffer><silent> <Esc> :call <SID>CloseNetrw()<CR>
autocmd FileType netrw nnoremap <buffer><silent> q     :call <SID>CloseNetrw()<CR>
...
function! s:CloseNetrw() abort
  for bufn in range(1, bufnr('$'))
    if bufexists(bufn) && getbufvar(bufn, '&filetype') ==# 'netrw'
      silent! execute 'bwipeout ' . bufn
      if getline(2) =~# '^" Netrw '
        silent! bwipeout
      endif
      return
    endif
  endfor
endfunction

Please note, always place autocmd inside a group.

score -3 · Answer 4 · answered Dec 25 '17 at 16:21

-3

typing q while in the buffer closes mine.

answered Dec 25 '17 at 16:21

alpha_989

901
7
15

How can I close the Netrw buffer?

4 Answers4