140

In Bash, I can do EDITOR=vim command and command will be run with EDITOR set to vim, but this won't affect the value of EDITOR in the shell itself. Is it possible to do this in cmd.exe?

sactiw
  • 103
Alexey Romanov
  • 2,338
  • Would Powershell answers be acceptable here as well? (https://superuser.com/q/1049430/185554 which did not limit itself to cmd.exe was closed as a duplicate of this) – Gert van den Berg Apr 20 '21 at 10:00
  • 2
    @GertvandenBerg I certainly wouldn't object, but I don't know if moderators would (or if I should edit question title/body to extend it). – Alexey Romanov Apr 20 '21 at 11:03

5 Answers5

89

Note that cmd /C "set "EDITOR=vim" && echo %EDITOR%" would not work.
Nor would cmd /C "setlocal ENABLEDELAYEDEXPANSION && set "EDITOR=vim" && echo !EDITOR!"

You would need:

  • the /V option, to enable delayed environment variable expansion using ! as delimiter.
  • no space between a command and the && (or add quotes)

That is:

C:\> cmd /V /C "set EDITOR=vim&& echo '!EDITOR!'"
'vim'
# or
C:\> cmd /V /C "set "EDITOR=vim" && echo '!EDITOR!'"
'vim'

As noted below by maoizm, it is cmd /V /C, not cmd /C /V (which would not work)

I can't think of any practical reason you'd ever actually want this within the context of a single command

Typically, you need this when you have to replace a value used multiple times in a long command line.
For instance, to deploy a file to Nexus (in multiple lines for readability):

cmd /v /c "set g=com.agroup&& set a=anArtifact&& set v=1.1.0&& \
           mvn deploy:deploy-file -Dfile=C:\path\!a!-!v!.jar \
           -Dpackaging=jar -DgroupId=!g! -DartifactId=!a! -Dversion=!v! \
           -DrepositoryId=nexus 
           -Durl=http://myserver/nexus/content/repositories/my-repo/"

Instead of having to replace group, artifact (used 2 times) and version in a long and complex command line, you can edit them at the beginning of said command. It is clearer/easier to manipulate and change the parameter values.

VonC
  • 14,508
  • 2
    Tested it on my machine with Windows 10 version 1607, the cmd prompt crashes. – Fernando Costa Bertoldi Dec 21 '16 at 20:37
  • Note that EDITOR will not be set to 'vim' but 'vim ' in the last command. Add the internal quotes to avoid the space in the end. – Zitrax Feb 03 '17 at 11:57
  • @Zitrax Right! I have edited the answer accordingly. – VonC Feb 03 '17 at 11:59
  • Based on given solution I created a way to access ERRORLEVEL of two commands that run on same command line: cmd /v /c "dir file1.txt >NUL 2>&1 & echo !ERRORLEVEL! & dir file2.txt >NUL 2>&1 & echo !ERRORLEVEL!" – sactiw May 10 '17 at 19:37
  • 4
    NB: interesting: the order of switches matters in this case. cmd /v/c "..." works, but cmd /c/v "..." fails -- hopefully it can save you 15 minutes – maoizm Jun 04 '17 at 11:12
  • This works and is clever, but it's unnecessary syntax noise unless you actually need parameter expansion. I can't think of any practical reason you'd ever actually want this within the context of a single command. If you know the value of EDITOR at the time the command is being executed, you'd just use it. Now if you were going to use it multiple times and the effort of typing the variable name were less than typing the actual value then it could be useful. – Derek Greer Jul 20 '17 at 23:22
  • 2
    @DerekGreer " I can't think of any practical reason": OK, I have edited the answer to add a practical reason. – VonC Jul 21 '17 at 06:20
  • Now that I see it actually used in the only way I thought it might be useful, I'm not sure even that is practical. The example you've provided would likely never be typed as an ad-hoc command, but rather would most generally be in a script where you'd have the opportunity to set variables to avoid such repetition as well as improve readability. It's still clever though. – Derek Greer Jul 21 '17 at 13:54
  • @DerekGreer: "I'm not sure even that is practical." An even more common example is commands in makefiles. The command is "in a script", for sure, but not at home, in a CMD batch file... Insanely harsh environment, either way (make or cmd), BTW, especially when combined!. :) – Sz. Aug 18 '19 at 17:03
  • 4
    @DerekGreer This is also useful (and commonly used in *Nix) for apps that read environment variables. (e.g. EDITOR=emacs git commit) On windows, it could also be used to load DLLs from a custom location, by setting DEVPATH https://docs.microsoft.com/en-us/dotnet/framework/configure-apps/how-to-locate-assemblies-by-using-devpath?redirectedfrom=MSDN – iCodeSometime Jan 23 '20 at 18:32
61

You can do it in windows like this no need for installing anything.

cmd /C "set EDITOR=vim && set"

You'll see a list of variables and you'll see EDITOR=vim, now run "set" again and it won't be listed.

You can do multiple &&'s to add additional commands:

cmd /C "set EDITOR=vim && do this && do that && otherstuff"

EDIT: /C exits the new cmd right away after running, if you produce output with the new one it will still be visible in the parent window.

You can opt to use /K in which case the new cmd window stays open at the end of the run.

Viper_Sb
  • 1,036
  • 2
  • 10
  • 12
  • 12
    Be careful. Setting the variable this way will result in a trailng space in the variable EDITOR: "vim ". To avoid the trailing space use: cmd /C "set "EDITOR=vim" && do this && do that" – Gerd K Apr 03 '15 at 12:00
  • 2
    This is not working on "Windows Server 2008", for example. I tried this: set name="username" && echo %username%. And username is empty. – akozin May 15 '15 at 12:10
  • @akozin Do you realize that you got the keyvalue backwards? Did you mean set name=foo&&echo %name% or set username=foo&&echo %username%? – Phrogz Jul 30 '15 at 23:00
  • @akozin see my answer below – VonC Aug 05 '15 at 06:03
  • Your cmd = OP's command? – Iulian Onofrei Oct 09 '20 at 07:47
  • An alternative to the trailing space issue can also be solved with something like: cmd /C "set EDITOR=vim&& do this && do that" where you remove the trailing space just before the && ... although it's a bit hacky. – degenerate Dec 28 '23 at 22:11
13

you can use ported util env from package CoreUtils in GnuWin32 http://gnuwin32.sourceforge.net/

  1. Setup it
  2. Check what directory with env.exe exists in %PATH% variable
  3. Use same way like linux version env EDITOR=vim command
Red Skotina
  • 153
  • 4
    maybe worth saying that if you have git/docker/msys/cygwin you'll already have a version of this. – xenoterracide Feb 26 '18 at 16:29
  • This is specially a good choice for those who have Git Bash installed (almost every programmer these days). You can use the C:\Program Files\Git\usr\bin\env.exe executable. – Marcelo Barros Jun 20 '21 at 15:52
6

Vonc's answer will work for commands that reference the variable as expanded (that is !FOO! instead of %FOO%)

However, It won't work if your command references a regular variable.

For example consider:

some-bat.bat (or any other executable/batch process)

echo %FOO%

And the main process:

set FOO=foo
cmd /V /C "set FOO=bar && some-bat.bat"

Returns foo instead of bar (a second execution would work though)

But still, you could concatenate a new cmd process to force the refresh of the variable.

Like this:

set "FOO=BAR" && cmd /c "echo %FOO%"

Or in case the main command already had to use a new cmd:

cmd /c "set FOO=BAR && cmd /c ^"echo %FOO%^""
Julio
  • 196
5

I have knocked up a batch file env.cmd which works more or less like the Linux env command:-

echo off
setlocal
for %%f in (%*) do (
  echo %%f|find "=" >nul:
  if errorlevel 1 goto DoCmd
  set %%f
  shift
)
:DoCmd
%1 %2 %3 %4 %5 %6 %7 %8 %9
endlocal

The only difference is that, because of the way cmd parses, the environment assignments need to be quoted, so your command would be:

env "EDITOR=vim" command [up to 8 parameters]

The batch file could be elaborated to remove the 8-parameter restriction by building up the command string within the for loop (delayed expansion will be needed).

AFH
  • 17,530