35

How do I take a string in Perl and split it up into an array with entries two characters long each?

I attempted this:

@array = split(/../, $string);

but did not get the expected results.

Ultimately I want to turn something like this

F53CBBA476

in to an array containing

F5 3C BB A4 76
hippietrail
  • 14,735
  • 16
  • 96
  • 147
Jax
  • 6,625
  • 4
  • 25
  • 37

4 Answers4

59
@array = ( $string =~ m/../g );

The pattern-matching operator behaves in a special way in a list context in Perl. It processes the operation iteratively, matching the pattern against the remainder of the text after the previous match. Then the list is formed from all the text that matched during each application of the pattern-matching.

Bill Karwin
  • 499,602
  • 82
  • 638
  • 795
41

If you really must use split, you can do a :

grep {length > 0} split(/(..)/, $string);

But I think the fastest way would be with unpack :

unpack("(A2)*", $string);

Both these methods have the "advantage" that if the string has an odd number of characters, it will output the last one on it's own.

Matt Simerson
  • 837
  • 1
  • 8
  • 20
mat
  • 12,363
  • 5
  • 38
  • 44
  • Since it looks like he is working with hex characters, so this is a bit of a moot point, but A only works for ASCII characters. The split should work for any encoding, but you might want to add a /s to the regex so "\n" will be matched by ".". – Chas. Owens Apr 28 '09 at 21:34
  • 3
    Should be `a2`, not `A2`. The former strips trailing whitespace, which is at best superfluous. – ikegami May 19 '11 at 16:28
6

Actually, to catch the odd character, you want to make the second character optional:

@array = ( $string =~ m/..?/g );
ChrisD
  • 61
  • 1
5

The pattern passed to split identifies what separates that which you want. If you wanted to use split, you'd use something like

my @pairs = split /(?(?{ pos() % 2 })(?!))/, $string;

or

my @pairs = split /(?=(?:.{2})+\z)/s, $string;

Those are rather poor solutions. Better solutions include:

my @pairs = $string =~ /..?/sg;  # Accepts odd-length strings.

my @pairs = $string =~ /../sg;

my @pairs = unpack '(a2)*', $string;
ikegami
  • 343,984
  • 15
  • 249
  • 495
  • Hi @ikegami, Is there a way I can divide this string into 4 parts such that 1st 2 parts has 2 chars each and last 2 parts have 3 chars each.. i.e `F5 3C BBA 476` – Bhagyesh Dudhediya Apr 04 '18 at 06:47