Not able to call Metadata API Service from LWC controller using Apex class

Question

How can I call a Metadata API from a LWC controller. I have a class which used Metadata API to fetch Entitlement process details which works fine in anonymous block but not with LWC

My code is below :

public with sharing class FetchEntitlementMetadata {

@AuraEnabled
public static string fetchData(){
// Instantiate the Metadata API service
MetadataService.MetadataPort metadataPort = new MetadataService.MetadataPort();
metadataPort.SessionHeader = new MetadataService.SessionHeader_element();
metadataPort.SessionHeader.sessionId = UserInfo.getSessionId();
// Specify the type (Entitlement Process)
String metadataType = 'EntitlementProcess';

// Fetch all Entitlement Process names from the org
MetadataService.ListMetadataQuery query = new MetadataService.ListMetadataQuery();
query.type_x = metadataType; // Use &quot;type_x&quot; to specify the metadata type
System.debug(UserInfo.getSessionId());
MetadataService.FileProperties[] fileProperties = metadataPort.listMetadata(new List&lt;MetadataService.ListMetadataQuery&gt; { query }, 50);

Set&lt;String&gt; entitlementProcessNames = new Set&lt;String&gt;();

for (MetadataService.FileProperties fileProperty : fileProperties) {
    // Decode the name to make it proper
    String decodedName = EncodingUtil.urlDecode(fileProperty.fullName, 'UTF-8');
    entitlementProcessNames.add(decodedName);

    System.debug('******' + decodedName);
}
List&lt;String&gt; fullNames = new List&lt;String&gt;{'Test'};

// Map to store process name as key and its values as category names and time in minutes
Map&lt;String, Map&lt;String, Integer&gt;&gt; processMap = new Map&lt;String, Map&lt;String, Integer&gt;&gt;();
// Read metadata for the specified Entitlement Process
MetadataService.IReadResult readResult = metadataPort.readMetadata(metadataType, fullNames);
MetadataService.Metadata[] mdInfo = readResult.getRecords();
// Process the metadata
for (MetadataService.Metadata md : mdInfo) {
    if (md instanceof MetadataService.EntitlementProcess) {
        MetadataService.EntitlementProcess entitlementProcess = (MetadataService.EntitlementProcess) md;
        String processName = entitlementProcess.fullName;

        for (MetadataService.EntitlementProcessMilestoneItem milestone : entitlementProcess.milestones) {
            // Filter milestones that have milestoneCriteriaFilterItems with 'Case.Category__c'
            List&lt;MetadataService.FilterItem&gt; criteriaFilterItems = milestone.milestoneCriteriaFilterItems;

            if (criteriaFilterItems != null) {
                for (MetadataService.FilterItem filterItem : criteriaFilterItems) {
                    if ('Case.Category__c'.equals(filterItem.field)) {
                        String milestoneName = milestone.milestoneName;
                        Integer minutesToComplete = milestone.minutesToComplete;
                        String values = filterItem.value;

                        // Split the comma-separated values and create entries in the map
                        List&lt;String&gt; individualValues = values.split(',');
                        for (String individualValue : individualValues) {
                            if (!processMap.containsKey(processName)) {
                                processMap.put(processName, new Map&lt;String, Integer&gt;());
                            }
                            processMap.get(processName).put(individualValue, minutesToComplete);
                        }
                    }
                }
            }
        }
    }
}
// Print the process map
System.debug('Process Map: ' + JSON.serializePretty(processMap));
return JSON.serialize(processMap);

}

}

When i run this in developer console using anonymous block it works fine, but when I use it in LWC it returns an error as below :

error{"status":500,"body":{"exceptionType":"System.CalloutException","isUserDefinedException":false,"message":"Web service callout failed: WebService returned a SOAP Fault: INVALID_SESSION_ID: This session is not valid for use with the API faultcode=sf:INVALID_SESSION_ID faultactor=","stackTrace":"Class.MetadataService.MetadataPort.listMetadata: line 13519, column 1\nClass.FetchEntitlementMetadata.fetchData: line 21, column 1"},"headers":{},"ok":false,"statusText":"Server Error","errorType":"fetchResponse"}

How can this be used in LWC? this is my LWC JS code

import { LightningElement } from 'lwc'; import fetchData from '@salesforce/apex/FetchEntitlementMetadata.fetchData'; export default class Metadatafetch extends LightningElement {

connectedCallback(){
    this.fetchData();
}
fetchData() {
    fetchData().then(result => {
        console.log('££££'+JSON.stringify(result))
    }).catch(error => {
        console.log('error'+JSON.stringify(error));
    })
}

}

This link has too many approaches so not sure which one to use as per latest releases — Sfdc, Oct 12 '23 at 18:42

score 2 · Answer 1 · answered Oct 12 '23 at 19:28

You will need a more powerful session to access Salesforce Metadata API.

When you invoke Apex from LWC it uses session Id from lightning domain which does give access to the Salesforce metadata due to security issues.

Here are couple of approved approaches

1. Using VF Page for a proxy session

   <apex:page>
     Start_Of_Session_Id{!$Api.Session_ID}End_Of_Session_Id
   </apex:page>

Apex Utility

   global class Utils {
    global static String getSessionIdFromVFPage(PageReference visualforcePage){
        String content = visualforcePage.getContent().toString();
        Integer s = content.indexOf('Start_Of_Session_Id') + 'Start_Of_Session_Id'.length(),
                e = content.indexOf('End_Of_Session_Id');
        return content.substring(s, e);
      }
    }

Then you will need something below

public static MetadataService.MetadataPort createService() {
    MetadataService.MetadataPort service = new MetadataService.MetadataPort();
    service.SessionHeader = new MetadataService.SessionHeader_element();
   //service.SessionHeader.sessionId = UserInfo.getSessionId();
   service.SessionHeader.sessionId = Utils.getSessionIdFromVFPage(Page.SessionId);
   return service;
 }

2. Using a Named Credential approach like this article talks about.

Not able to call Metadata API Service from LWC controller using Apex class

1 Answers1